test esp32 — ESP32 simulation

An interactive ESP32 circuit simulation you can run free in your browser on Velxio, by marismendi-8551.

Components

Sketch code

// asignar pines a variables
#define PIN_CONTROL 21
#define PIN_REGISTRANDO 19
#define PIN_SALIDA 18

#define MS_POR_BIT 100

// variables para estado de los pines
int valor_pcontrol = 0;

// partes del mensaje a modular
const char* PREAMBULO = "{";
const char* FINAL = "}";
String contenido = "";
String mensaje = "";

int registrando = 0;

// geminiteado
String textoABinarioASCII(const String& texto) {
  String binario = "";
  binario.reserve(texto.length() * 8);

  for (size_t i = 0; i < texto.length(); i++) {
    uint8_t codigoAscii = static_cast<uint8_t>(texto[i]);
    for (int bit = 7; bit >= 0; bit--) {
      binario += ((codigoAscii >> bit) & 0x01) ? '1' : '0';
    }
  }

  return binario;
}

// geminiteado
String binarioATextoASCII(const String& binario) {
  String texto = "";
  size_t totalBits = binario.length() - (binario.length() % 8);
  texto.reserve(totalBits / 8);

  for (size_t i = 0; i < totalBits; i += 8) {
    uint8_t caracter = 0;
    for (int bit = 0; bit < 8; bit++) {
      caracter <<= 1;
      if (binario[i + bit] == '1') {
        caracter |= 0x01;
      }
    }
    texto += static_cast<char>(caracter);
  }

  return texto;
}

void enviarSenal(String binario) {
  for(int i = 0; i < binario.length() + 1; i++) {
    char bit = binario.charAt(i);
    Serial.println(bit);
    if(bit == '1') {
      tone(PIN_SALIDA, 1200);
    } else {
      tone(PIN_SALIDA, 2200);
    }
    delay(MS_POR_BIT);
    noTone(PIN_SALIDA);
    //delay(MS_POR_BIT);
  }
}

void setup() {
  Serial.begin(115200);
  pinMode(PIN_CONTROL, INPUT_PULLDOWN);
  pinMode(PIN_REGISTRANDO, OUTPUT);
  pinMode(PIN_SALIDA, OUTPUT);
  delay(500); // para dar chance a que el pin control asiente en low
}

void loop() {
  valor_pcontrol = digitalRead(PIN_CONTROL); 

  if (registrando) {
    if (Serial.available() > 0) {
      contenido = Serial.readString();
    }
  }

  // boton control presionado
  if (valor_pcontrol == HIGH && registrando == 0) {
    registrando = 1;
    digitalWrite(PIN_REGISTRANDO, registrando);

    Serial.println("Registrando");

    // previene que capture y envie infinito al mantener boton
    while (digitalRead(PIN_CONTROL) == HIGH) {
      delay(20);
    }
  }
  // boton control presionado de nuevo
  else if (valor_pcontrol == HIGH && registrando == 1) {
    registrando = 0;
    digitalWrite(PIN_REGISTRANDO, registrando); 

    mensaje += PREAMBULO;     
    mensaje += contenido;
    mensaje += FINAL;
    String binario = textoABinarioASCII(mensaje);

    Serial.print("ascii original: ");
    Serial.println(mensaje);
    Serial.print("binario: ");
    Serial.println(binario);
    Serial.print("binario a ascii: ");
    Serial.println(binarioATextoASCII(binario));
    enviarSenal(binario);
    Serial.println("Enviado");

    mensaje = "";
    contenido = "";

    // previene que capture y envie infinito al mantener boton
    while (digitalRead(PIN_CONTROL) == HIGH) {
      delay(20);
    }
  }
}